Bei Windows ist es möglich, dass sich nach dem Hochfahren des PCs automatisch ein Benutzer anmeldet. Wenn sich der Rechner in einer Arbeitsgruppe befindet, kann man dies über ein Fenster einstellen. An das entsprechende Fenster gelangt man über folgende Befehle: control userpasswords (Windows 2000), control userpasswords2 (Windows XP/2003/Vista) und netplwiz (Windows Vista). Einfach den Haken bei “Benutzer müssen Benutzernamen und Kennwort eingeben” entfernen und “Übernehmen” klicken. Im erscheinenden Dialog “Automatische Anmeldung” muss man jetzt nur noch den Benutzernamen angeben und das Kennwort bestätigen.

Wenn der Computer allerdings Mitglied in einer Dömäne ist, funktioniert der Weg leider nicht! Hier muss man den direkten Weg über die Registry gehen. Die Werte müssen als Zeichenkette unter folgenden Schlüssel angelegt werden:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon

  • AutoAdminLogon = 1
  • DefaultDomainName = Domänenname
  • DefaultUserName = Benutzername
  • DefaultPassword = Kennwort

Und da wir es bei ein paar Rechnern einstellen mussten, habe ich ein VBScript geschrieben, dass die Werte abfragt und einträgt. (Bei leeren Werte wird die automatischen Anmeldung übrigens deaktiviert.)

AutomatischeAnmeldung.vbs

'-------------------------------------------------------------------------------
' An die eigenen Bedürfnisse anpassen...
'-------------------------------------------------------------------------------
Private Const DEFAULT_DOMAINNAME = ""
Private Const DEFAULT_USERNAME = ""
Private Const DEFAULT_PASSWORD = ""
'-------------------------------------------------------------------------------

Dim oWshShell, sDefaultDomainName, sDefaultUserName, sDefaultPassword, iChoice

sDefaultDomainName = InputBox("Geben Sie bitte den Domänennamen für die automatische Anmeldung an:", "Automatische Anmeldung (Domänenname)", DEFAULT_DOMAINNAME)
sDefaultUserName = InputBox("Geben Sie bitte den Benutzernamen für die automatische Anmeldung an:", "Automatische Anmeldung (Benutzername)", DEFAULT_USERNAME)
sDefaultPassword = InputBox("Geben Sie bitte das Kennwort für die automatische Anmeldung an:", "Automatische Anmeldung (Kennwort)", DEFAULT_PASSWORD)

Set oWshShell = CreateObject("WScript.Shell")
If (sDefaultDomainName <> "") And (sDefaultUserName <> "") And (sDefaultPassword <> "") Then 'Wenn Werte angegeben wurden...
  oWshShell.RegWrite "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\AutoAdminLogon", "1", "REG_SZ"
  oWshShell.RegWrite "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\DefaultDomainName", sDefaultDomainName, "REG_SZ"
  oWshShell.RegWrite "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\DefaultUserName", sDefaultUserName, "REG_SZ"
  oWshShell.RegWrite "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\DefaultPassword", sDefaultPassword, "REG_SZ"

  MsgBox "Automatische Anmeldung aktiviert für:" & vbCrLf & vbCrLf & _
         "   Domänenname: " & sDefaultDomainName & vbCrLf & _
         "   Benutzername: " & sDefaultUserName & vbCrLf & _
         "   Kennwort: " & sDefaultPassword & vbCrLf, vbOKOnly, "Automatische Anmeldung aktiviert"
Else 'Wenn KEINE Werte angegeben wurden...
  iChoice = MsgBox("Möchten Sie die Werte für die automatische Anmeldung aus der Registrierung löschen?", vbQuestion + vbYesNo , "Automatische Anmeldung deaktivieren?")
  If (iChoice = vbYes) Then 'Wenn "Ja" gewählt wurde...
    oWshShell.RegDelete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\AutoAdminLogon"
    oWshShell.RegDelete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\DefaultDomainName"
    oWshShell.RegDelete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\DefaultUserName"
    oWshShell.RegDelete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\DefaultPassword"

    MsgBox "Die Automatische Anmeldung wurde deaktiviert.", vbOKOnly, "Automatische Anmeldung deaktiviert"
  End If
End If

Download